Micro Servomotoren MG90s und SG90 - Produktvorstellung

In diesem Video möchten wir Ihnen den Servos MG90s und SG90 vorstellen. Im Rahmen des Videos werden die technischen Spezifikationen und Unterschiede beider Varianten erklärt. Zusätzlich zeigen wir mehrere Beispielschaltungen, um darzustellen, wie die Servos eingesetzt werden können und wie die Verkabelung funktioniert.

Hier finden Sie die vorgestellten Servos:

MG90S Micro Servomotor

SG90 Micro Servo Motor

Verdrahtung SG90 Beispiel: 

Code SG90 Beispiel:

/*
    ___ _____        ____       ___                      
   /   /__  /       / __ \___  / (_)   _____  _______  __
  / /| | / / ______/ / / / _ \/ / / | / / _ \/ ___/ / / /
 / ___ |/ /_/_____/ /_/ /  __/ / /| |/ /  __/ /  / /_/ / 
/_/  |_/____/    /_____/\___/_/_/ |___/\___/_/   \__, /  
                                                /____/   
  Produkt, Datenblatt und Pinout unter:
  https://www.az-delivery.de/

  Projekt:  MG90S und SG90S Servo
  Datum:    03/2022

*/

#include <ESP32Servo.h>

Servo mg90sServo;
Servo sg90Sevro;

int servoPinMG90s = 14;
int servoPinSG90 = 25;

void setup() {
  Serial.begin(115200);
  delay(250);

  mg90sServo.setPeriodHertz(50);    
	mg90sServo.attach(servoPinMG90s); 

  sg90Sevro.setPeriodHertz(50);    
	sg90Sevro.attach(servoPinSG90); 

  mg90sServo.write(0);
  sg90Sevro.write(0);
 
}

void loop() {

 if (Serial.available()) {
    String inData = "";
    inData = Serial.readStringUntil('\n');
    if (inData.startsWith("m")) {
      servoRotation(mg90sServo);
    }
    else if (inData.startsWith("u")) {
      servoRotation(sg90Sevro);
    }
 }
 
}

void servoRotation(Servo funktionsServo){
  for (int i = 0; i <= 180; i += 5) {
    //Servo-Position wird in 20°-Schritten gesetzt
    funktionsServo.write(i);
    Serial.print("Servo-Position: ");
    Serial.println(i);
    delay(300);
  }
}

Code Schere Stein Papier (MG90s oder SG90):

/*
    ___ _____        ____       ___                      
   /   /__  /       / __ \___  / (_)   _____  _______  __
  / /| | / / ______/ / / / _ \/ / / | / / _ \/ ___/ / / /
 / ___ |/ /_/_____/ /_/ /  __/ / /| |/ /  __/ /  / /_/ / 
/_/  |_/____/    /_____/\___/_/_/ |___/\___/_/   \__, /  
                                                /____/   
  Produkt, Datenblatt und Pinout unter:
  https://www.az-delivery.de/

  Projekt:  MG90S und SG90S Servo
  Datum:    03/2022

*/

#include <ESP32Servo.h>

String bot ="";
//Servo
const uint8_t SERVO_NUM = 3;
Servo servoArray[SERVO_NUM];  
uint8_t servoPins[SERVO_NUM]={14,27,26};
const uint8_t ausgansposition = 70;
String auswahl[SERVO_NUM] = {"schere", "stein", "papier"};

//Ultrasonic Sensor
const uint8_t trigPin = 5;
const uint8_t echoPin = 18;
#define SOUND_SPEED 0.034
long duration;
float distanzCM;

bool distanzUnterschritten(){
  //Messung
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);

  duration = pulseIn(echoPin, HIGH);
  // Calculate the distance
  distanzCM = duration * SOUND_SPEED/2;

  return (distanzCM<=10);
}

void setup() {
  Serial.begin(115200);

  //Servos einrichten
  for (uint8_t i = 0; i < SERVO_NUM; i++) {
      servoArray[i].setPeriodHertz(50);
      servoArray[i].attach(servoPins[i]);
      servoArray[i].write(ausgansposition);
      Serial.println(i);
  }

  //ultrasonic
  pinMode(trigPin, OUTPUT); 
  pinMode(echoPin, INPUT); 
}

void loop() {
    if(distanzUnterschritten()) {
          uint8_t zufallszahl = random(0,SERVO_NUM);
          bot=auswahl[zufallszahl];
          servoArray[zufallszahl].write(0);
          //servo write

          //debug
          Serial.print("bot: ");
          Serial.print(bot);
          Serial.println("--------------------");
          delay(3000);

          servoArray[zufallszahl].write(ausgansposition);
      }
}