Scary, spooky Halloween 2022

Ehe man sich versieht, klingelt es an der Tür und es heißt wieder „Süßes oder Saures?“

Halloween kommt immer so plötzlich. Meist schaffe ich es nur, ein paar Süßigkeiten zu kaufen. Aber dieses Jahr möchte ich etwas basteln, womit ich die Kinder ein wenig erschrecken kann. Die Idee: Bei Annäherung (Bewegungsmelder oder Entfernungsmesser) hört man zunächst das Geschrei einer Krähe, und dann fliegt das Biest auch schon über die Köpfe hinweg.

Wir brauchen an Hardware:

Der „Flug der Krähe“ wird simuliert, indem eine Attrappe mit einer Laufrolle auf einer Schnur bewegt wird. Dabei wird die Schnur an einer Seite mit einem Servo-Arm höher oder tiefer gestellt. Um genügend Gefälle zu erzielen, habe ich den Holzstiel von meinem Lieblingseis als Verlängerung des Servo-Arms angeschraubt.

Die gute Nachricht für den wenig talentierten Bastler ist die Tatsache, dass es am 31. Oktober früh dunkel wird. Die „Krähe“ muss also nicht perfekt nachgebildet werden, eine Klo-Rolle, etwas Draht und schwarzer Stoff/Plastiktüte genügen für die Illusion vollkommen.

Deshalb können wir uns zunächst auf die Programmierung des Sketches stürzen. Bei den Programmzeilen für den Auslöser erwarte ich keine Schwierigkeiten, im Wesentlichen werde ich Teile des Beispiel-Sketches „button“ verwenden. Deshalb konzentriere ich mich zunächst auf den MP3-Player. Dazu lade ich von der Produktseite das Datenblatt und die Schaltung (Schematics) herunter. Da ich für den MP3-Player ohnehin ein Breadboard benötige, entscheide ich mich für einen Nano als Mikrocontroller. Dabei benutze ich die gleichen Pins wie auf dem Schaltbild, also D10 und D11.

Um eine geeignete Programm-Bibliothek (library) zu finden, gebe ich im Bibliotheksverwalter der Arduino-IDE in der Suchzeile DFPlayer ein. Am aktuellsten ist die Bibliothek von Angelo mit Namen DFRobotDFPLayerMini. Nach der Installation hat man im wesentlichen die gleichen Informationen, die man auf github unter https://github.com/DFRobot/DFRobotDFPlayerMini findet, einschließlich einiger Beispiele und eines pdf-Dokuments mit der ausführlichen Beschreibung des mp3-Players.

Andreas Wolter hatte eine schöne Anwendung mit guten Erklärungen auch in seinem Blog-Beitrag vom 29.03.2021 beschrieben:

https://www.az-delivery.de/blogs/azdelivery-blog-fur-arduino-und-raspberry-pi/der-sprechende-farbdetektor-mit-dfplayer-und-tcs3200-teil-1

Ich staune über die vielfältigen Möglichkeiten des kleinen mp3-Players mit µSD-Card-Reader. Die meisten Funktionen bzw. Anschlüsse werde ich gar nicht benutzen. Mehr dazu später.

Von der Internetseite https://quicksounds.com/library/sounds/crow lade ich einen geeigneten Sound herunter und speichere diesen auf der µSD-Karte im Verzeichnis mp3 als 0001.mp3 ab. Dazu noch ein schauriges Gelächter als 0002.mp3, um ggf. die Halloween-Stimmung zu steigern. Hier die Links zu den von mir gewählten Geräuschen: 0001.mp3 bzw. 0002.mp3

Ich beginne mit dem Beispiel-Sketch GetStarted und modifiziere diesen im Hinblick auf meine Erfordernisse.

Hier zunächst die Pinbelegung des mp3-pPlayers mit Beschreibung:

Von den 16 Pins benutze ich nur Pin 1 und 7 für die Spannungsversorgung, also 5V und Ground, an Pin 6 und 8 wird ein kleiner Lautsprecher mit max. 3 Watt angeschlossen, und die Datenübertragung vom Mikrocontroller erfolgt über Pins 2 und 3, die serielle Schnittstelle UART.

Da die AVR-Mikrocontroller mit ATMega328 nur eine serielle Hardware-Schnittstelle haben, benutze ich die Pins 10 und 11 für eine SoftwareSerial-Schnittstelle. Wie üblich, werden RX und TX über Kreuz verbunden und (aufgepasst:) zwischen Nano D11 (TX) und mp3-Player Pin 2 (RX) kommt noch ein Widerstand mit 1 kOhm wegen der Bemerkung 3,3V TTL level (s.o.).

Hier nun der modifizierte Beispiel-Sketch (download):

#include "Arduino.h"
#include "SoftwareSerial.h"
#include "DFRobotDFPlayerMini.h"

// declare global variables
uint16_t vol;

SoftwareSerial mySoftwareSerial(10, 11); // RX, TX
DFRobotDFPlayerMini myDFPlayer;
void printDetail(uint8_t type, int value);

void setup()   {
  mySoftwareSerial.begin(9600);
  Serial.begin(9600);
  Serial.println();
  Serial.println(F("DFRobot DFPlayer Mini Demo"));
  Serial.println(F("Initializing DFPlayer"));
  myDFPlayer.begin(mySoftwareSerial);      //) {  //Use SoftwareSerial to communicate with mp3.
  Serial.println(F("DFPlayer Mini online."));
}

void player()   {
  vol = map(analogRead(A0),0,1023,0,30);
  Serial.print("volume: ");
  Serial.println(vol);
  myDFPlayer.volume(vol);  //Set volume value. From 0 to 30
  myDFPlayer.play(1);  //Play the first mp3
}

void loop()   {
  player();
  delay(20000);
  Serial.println("Again");
}

Meine Veränderungen beschränken sich auf die Verwendung eines Potis für die Lautstärkeregelung an Eingang A0, gemapped auf den Wertebereich 0 bis 30 der Programm-Bibliothek, sowie die Verlegung der wesentlichen Programmzeilen für den Player in eine selbstdefinierte Funktion player(), die vom Hauptprogramm aufgerufen wird.

Im nächsten Schritt möchte ich den Bewegungsmelder einbinden, der zunächst das Krähengeräusch des mp3-Players triggern und danach den Servo für die Schnur betätigen soll.

Der Bewegungsmelder funktioniert wie ein Schalter. Empfindlichkeit des Sensors und Einschaltdauer können an zwei Trimm-Potis eingestellt werden. Wir benötigen nur das Einschaltsignal zum Triggern des geplanten Ablaufs. Ich verwende das Programmbeispiel „button“ (Beispiele->02.Digital) und schließe den Signal-Pin OUT an D2 an. Die Spannungsversorgung erfolgt mit 5V und Ground. 

Hier der Sketch, bei dem die LED_BUILTIN beim Erkennen einer Bewegung eingeschaltet wird. Wie gesagt, benötigen wir später nur if (buttonState == HIGH) 

// constants won't change. They're used here to set pin numbers:
const int buttonPin = 2;     // the number of the pushbutton pin
const int ledPin =  13;      // the number of the LED pin
 
// variables will change:
int buttonState = 0;         // variable for reading the pushbutton status
 
void setup() {
  // initialize the LED pin as an output:
  pinMode(ledPin, OUTPUT);
  // initialize the pushbutton pin as an input:
  pinMode(buttonPin, INPUT);
}
 
void loop() {
  // read the state of the pushbutton value:
  buttonState = digitalRead(buttonPin);
 
  // check if the pushbutton is pressed. If it is, the buttonState is HIGH:
  if (buttonState == HIGH) {
    // turn LED on:
    digitalWrite(ledPin, HIGH);
  } else {
    // turn LED off:
    digitalWrite(ledPin, LOW);
  }
}

Anschließend wird dieser Sketch mit dem Programmcode des MP3-Players "verheiratet" (download).

#include "Arduino.h"
#include "SoftwareSerial.h"
#include "DFRobotDFPlayerMini.h"

// declare global variables
uint16_t vol;
const int buttonPin = 2;     // the number of the pushbutton pin
int buttonState = 0;         // variable for reading the pushbutton status

SoftwareSerial mySoftwareSerial(10, 11); // RX, TX
DFRobotDFPlayerMini myDFPlayer;
void printDetail(uint8_t type, int value);

void setup()   {
  Serial.begin(9600);
  mySoftwareSerial.begin(9600);
  // initialize the pushbutton pin as an input:
  pinMode(buttonPin, INPUT);  
  myDFPlayer.begin(mySoftwareSerial);      //) {  //Use SoftwareSerial to communicate with mp3.
  Serial.println(F("DFPlayer Mini online."));
}

void player()   {
  vol = map(analogRead(A0),0,1023,0,30);
  Serial.print("volume: ");
  Serial.println(vol);
  myDFPlayer.volume(vol);  //Set volume value. From 0 to 30
  myDFPlayer.play(1);  //Play the first mp3
  myDFPlayer.stop();
}

void loop()   {
  // read the state of the pushbutton value:
  buttonState = digitalRead(buttonPin);

  // check if the pushbutton is pressed. If it is, the buttonState is HIGH:
  if (buttonState == HIGH) {
    player();
    delay(20000);
    Serial.println("Again");
  }
}

Auch für den Servo gibt es einen Beispiel-Sketch, den ich modifizieren kann. Auch hier verschiebe ich den Hauptteil des Programms „Servo_Sweep“ in zwei Funktionen, um den Servo zügig, aber nicht zu abrupt jeweils in die Stellungen 0° bzw. 180° zu fahren. Die Länge des Servo-Arms hängt natürlich von der Länge der Schnur ab; ein gewisses Gefälle ist nötig, damit die Vogel-Attrappe schnell genug „fliegt“. Hier der modifizierte Sketch (download):

#include <Servo.h>

Servo myservo;  // create servo object to control a servo
// twelve servo objects can be created on most boards

int pos = 0;    // variable to store the servo position

void setup() {
  Serial.begin(9600);
  myservo.attach(13);  // attaches the servo on pin 9 to the servo object
  myservo.write(0);
}

void servoUp()   {
  for (pos = 0; pos <= 180; pos += 1) { // goes from 0 degrees to 180 degrees
    // in steps of 1 degree
    myservo.write(pos);              // tell servo to go to position in variable 'pos'
    delay(10);                       // waits 10 ms for the servo to reach the position
  }
}

void servoDown()   {
  for (pos = 180; pos >= 0; pos -= 1) { // goes from 180 degrees to 0 degrees
    myservo.write(pos);              // tell servo to go to position in variable 'pos'
    delay(10);                       // waits 10 ms for the servo to reach the position
  }
}

void loop() {
  servoUp();
  delay(5000);
  servoDown();
  delay(5000);
}

Am Ende wird auch dieser Teil in den Sketch mit Bewegungsmelder und mp3-Player integriert und ausprobiert. (download)

/***************************************************
* A spooky Halloween joke with voice of a crow from mp3 player, 
* a crow mock-up moved on a string by servo
* triggered by motion sensor
* for AZ-Delivery
* This example code is in the public domain.
****************************************************/

#include "Arduino.h"
#include "SoftwareSerial.h"
#include "DFRobotDFPlayerMini.h"
#include <Servo.h>
Servo myservo;  // create servo object to control a servo

// declare global variables
uint16_t vol;
const int buttonPin = 2;     // the number of the pushbutton pin
int buttonState = 0;         // variable for reading the pushbutton status
int pos = 0;    // variable to store the servo position

SoftwareSerial mySoftwareSerial(10, 11); // RX, TX
DFRobotDFPlayerMini myDFPlayer;
void printDetail(uint8_t type, int value);

void setup()   {
  Serial.begin(9600);
  mySoftwareSerial.begin(9600);
  // initialize the pushbutton pin as an input:
  pinMode(buttonPin, INPUT);  
  myDFPlayer.begin(mySoftwareSerial);      //) {  //Use SoftwareSerial to communicate with mp3.
  Serial.println(F("DFPlayer Mini online."));
  myservo.attach(13);  // attaches the servo on pin 13 to the servo object
  myservo.write(0);  
}

void player(int i)   {
  vol = map(analogRead(A0),0,1023,0,30);
  Serial.print("volume: ");
  Serial.println(vol);
  myDFPlayer.volume(vol);  //Set volume value. From 0 to 30
  myDFPlayer.play(i);  //Play the mp3 file
}

void servoUp()   {
  for (pos = 0; pos <= 180; pos += 1) { // goes from 0 degrees to 180 degrees
    // in steps of 1 degree
    myservo.write(pos);              // tell servo to go to position in variable 'pos'
    delay(10);                       // waits 10 ms for the servo to reach the position
  }
}

void servoDown()   {
  for (pos = 180; pos >= 0; pos -= 1) { // goes from 180 degrees to 0 degrees
    myservo.write(pos);              // tell servo to go to position in variable 'pos'
    delay(10);                       // waits 10 ms for the servo to reach the position
  }
}

void loop()   {
  // read the state of the pushbutton value:
  buttonState = digitalRead(buttonPin);

  // check if the pushbutton is pressed. If it is, the buttonState is HIGH:
  if (buttonState == HIGH) {
    player(1);
    delay(8000);
    servoUp();
    delay(20000);
    servoDown();    
    delay(20000);
    Serial.println("Again");
  }
}

Im Hauptprogramm void loop() wird zunächst auf den Trigger vom Bewegungsmelder gewartet, dann der mp3-Player aktiviert. Da dieser die mp3-Datei unabhängig vom Mikrocontroller abspielt, werden einige Sekunden delay eingefügt, bevor der Servo-Arm nach oben schwingt (Funktion servoUp()), um die Krähen-Attrappe in Bewegung zu setzen. Nach einer gewissen Zeit wird die Attrappe mit servoDown() wieder in die Startposition gebracht und die nächste Kinderschar kann erschreckt werden.

Aufgrund der baulichen Situation bei uns hat die Umsetzung nicht so geklappt, wie geplant. Zu groß der Abstand zwischen den Endpunkten der Leine - damit kaum Gefälle, und zu leicht die Attrappe, die aufgrund geringer Höhe der Leine gefahrlos benutzt werden kann. Erste alternative Lösung: Leine samt Attrappe mit einem Motor und Umlenkrolle bewegen. Zweite alternative Lösung: leichtes U-Profil am Servo befestigen und die Attrappe schwenken. Das klappt bei uns prima.

Hier der Link zu dem leicht modifizierten Sketch (Winkelbereich 10° bis 170° und Einfügen Gelächter)
(download).

Zum Schluss noch der gesamte Schaltplan sowie das Bild unserer Krähen-Attrappe, bestehend aus einem Bügel, zwei Tüten und einem gefilzten Kopf; eine Hexe mit Besen wäre eine gute Alternative. Viel Spaß beim Nachbauen.

Es folgt hier noch ein Video, dass am Tage aufgenommen wurde. Es handelt sich um einen Versuchsaufbau. An Halloween ist es natürlich dunkel und es wird auch etwas geschmückt sein. Man hört die Geräusche aus dem MP3 Player. Die Attrappe bewegt sich, nachdem der Bewegungssensor meine Bewegung Richtung Haus detektiert hat.