Wieder nähert sich die Halloween-Nacht. Zeit für geschnitzte Kürbisse, „Süßes oder Saures“, schwarze Katzen und Hexen - gruselige und unheilvolle Wesen. Sie verlieren für eine Nacht im Jahr ihren schrecklichen Ruf und machen sie zu einer unterhaltsamen Festnacht auf der ganzen Welt.

In diesem Projekt werden wir eine kleine hölzerne Box konstruieren, um Geister und alle, die sich mit ihrem „Süßes oder Saures“ nähern, abzuschrecken. Sie erwartet eine gruselige Überraschung in der Kiste.

Es wird uns ein Monster durch die Löcher der hölzernen Kiste beobachten. Man wird seine Anwesenheit spüren, da es versuchen wird, aus der Kiste zu entkommen und die Kiste dadurch bewegt wird. Wenn man sich nähert, wird es denjenigen mit seinen roten Augen durch eines der Löcher beobachten. Wenn man sich weiterhin nähert, wird es den Deckel der Kiste anheben, um besser sehen zu können. Nähert man sich dann noch weiter, um die „Süßes oder Saures“-Belohnung zu nehmen, wird es seine Klaue durch ein Loch stecken, um denjenigen zu fangen.

Beginnen wir mit dem Projekt für Halloween 2023.

Benötigte Materialien

• 1 Mikrocontroller Board AZ-ATmega328-Board
• 5 MG90S Micro Servomotor
• 1 Mini Breadboard 400 Pin mit 4 Stromschienen
• 1 HC-SR04 Ultraschall Modul Entfernungsmesser
• 1 Mini MP3 Player DFPlayer Modul
• 1 2er Set DFplayer Mini 3 Watt 8 Ohm Mini-Lautsprecher
• 4 rote LEDs
• 4 330 Ohm Widerstände
• 1 1K Ohm Widerstand
• Jumper Wire Kabel M2M/ F2M / F2F
• Batterien/Akkus
• 3 mm dicke Balsaholzplatte
• Holzleim

Erforderliche Software

• Arduino IDE
• DFPlayer Mini Bibliothek von DFRobot (DFRobotDFPlayerMini.h)
• PCA9685-Bibliothek (Adafruit_PWMServoDriver.h)
• Ultraschallsensor-Bibliothek (SR04.h)
• Sketch als Download: the_box_monster.ino
• Klangdateien 1.mp3, 2.mp3, 3.mp3 und 4.mp3

Schaltung und Beschreibung der verwendeten Module

Download der Schaltung

Wir verwenden den Ultraschallsensor HC-SR04, um die Entfernung zu Personen zu messen. Für die Soundwiedergabe nutzen wir ein Set bestehend aus dem DFPlayer Modul und dem Lautsprecher DFPlayer Mini. Für die erforderlichen Bewegungen verwenden wir fünf MG90S-Servomotoren, die wir mit dem Modul PCA9685 16-Kanal 12-Bit-PWM-Servotreiber steuern. Um die Augen des Monsters zu simulieren, verwenden wir vier rote LEDs, an die zusätzlich jeweils einer von vier 330-Ohm-Widerstände angeschlossen werden muss. Außerdem verwenden wir einen 1K Ohm-Widerstand im MP3-Player-Modul, um die Spannung auf der Kommunikationsleitung anzupassen.

Alle zuvor genannten Module werden vom AZ-ATmega328-Board-Mikrocontroller gesteuert. Das gesamte System wird mit 5V Gleichstrom über ein Netzteil betrieben. Alternativ kann auch ein Batteriepack mit 5V Gleichstrom verwendet werden.

Funktionstest der Komponenten ohne Box:

 

Wenn die Videos nicht angezeigt werden, überprüfen Sie bitte die Cookie-Einstellungen Ihres Browsers

Montage

Ich habe für den Anfang Bauteile aus Pappe zugeschnitten. Später habe ich das auf Holz übertragen.

Das erste, was zu montieren ist, ist der Boden der Box. Dann müssen wir die Stützen installieren, um die Servomotoren 0 und 4, die die Box bewegen zu montieren. In der Mitte des Bodens muss ein Loch gebohrt werden, um alle Kabel zu verlegen, die die Komponenten im Inneren der Box mit dem Mikrocontroller, dem MP3-Player, den Widerständen und dem PCA3685-Modul zu verbinden.

Dann installieren wir die linke Wand, an der der Servomotor 1 montiert wird. Außerdem die Baugruppe zum Öffnen der Box und Servomotor 2, der die Augen beim Öffnen der Box bewegt.

Dann folgt die rechte Wand für den Servomotor 3, der den Arm des Monsters bewegt.

Wir müssen nun das Teil montieren, das den Deckel öffnet. Es wird mit dem Servomotor verbunden, der die Augen des Monsters bewegt. Dieses Teil muss zuerst am Servomotor 1 befestigt werden, bevor der Servomotor 2 mit dem Bauteil mit den zwei beweglichen LEDs installiert wird.

Die Baugruppe, die die Klaue bewegt, besteht aus zwei Teilen. Sie wird später am Servomotor 3 befestigt.

Außerdem müssen wir eine Halterung für den Lautsprecher und den Ultraschallsensor anbringen.

Die Wände sollten kleine 3 mm Aussparungen haben, um eine Seite mit der anderen verbinden zu können.

In die Außernseiten der Box schneiden wir Rillen, um Holzbretter zu imitieren.

Zuerst werden die rechteckigen Teile an der Außenseite der Box zusammengeklebt. Zwei kürzere oben, zwei längere an den Seiten.

Auf der Innenseite der Seitenflächen der Box werden die Platten für den Servomotor installiert, um sie zu bewegen.

Der Deckel der Box hat größere Abmessungen, da er den gesamten äußeren Umfang der Seitenflächen abdecken muss. An der Rückseite und der Oberseite werden zwei kleine Platten als Scharniere angebracht.

Sobald wir die Box zusammengebaut haben, beginnen wir mit der Installation der Komponenten.

Zuerst installieren wir die Servomotoren 0 und 4, die die Box bewegen werden. Dann installieren wir den Lautsprecher und anschließend den Ultraschallsensor HC-SR04. Die Kabel werden durch das Loch geführt.

Jetzt werden wir den Servomotor 1 in seiner Halterung befestigen, danach das Teil, das den Kasten öffnet. Anschließend der Servomotor 2 mit dem Satz beweglicher LEDs.

Jetzt ist der Servomotor 3 an der Reihe, der den Arm des Monsters bewegt. Wenn wir ihn befestigt haben, bauen wir den Arm des Monsters ein. Wir müssen die kleine Halterung montieren, in der die Führungswelle des Arms installiert wird.

Wir dürfen nicht vergessen, die beiden festen roten LEDs auf der Halterung des Servomotors 1 und die beiden beweglichen LEDs auf dem Servomotor 2 zu installieren.

Um die Löcher zu schneiden, hinter denen sich die LEDs und der Sensor befinden, habe ich eine transparente Folie als Schablone verwendet. Die Öffnungen habe ich dann auf das Bauteil übertragen und ausgeschnitten.

Die Bauteile sind aus Holz gefertigt. Die inneren Teile und das Innere der Kistenwände werden schwarz bemalt, damit sie von außen nicht sichtbar sind.

Die beiden Servomotoren, die die Kiste bewegen, sind in das Bodenbauteil eingebaut. An der linken Wand sind die beiden statischen LEDs und der Servomotor installiert, der den Kistendeckel anhebt. Außerdem der Servomotor, der zwei LEDs bewegt. An der rechten Wand ist der Servomotor installiert, der über einen Mechanismus die Kralle aus der Kiste bewegt.

Ich habe hier eine Kralle verwendet, aber beispielsweise kann auch die Hand eines Skelets angebracht werden. An den beiden Seiten der Kiste müssen wir zwei kleine Regale installieren, damit die seitlichen Servomotoren den Kasten anheben.

Download der Skizze

Funktionstest der Komponenten in der Box:

 

Beschreibung des Prgrammblaufs und des Sketches

Der Ultraschallsensor HC-SR04 sendet Signale aus und wenn ein Signal von einem Objekt reflektiert wird, erfasst der Sensor dieses empfangene Signal. Der Mikrocontroller berechnet die Zeit, die das Signal vom Absenden bis zum Empfang benötigt hat. Mit Hilfe der Schallgeschwindigkeit in der Luft wird dann die Entfernung berechnet. Solange der Abstand 200 cm oder mehr beträgt, passiert nichts. Wenn ein Objekt oder eine Person zwischen 200 und 150 cm erkannt wird, leuchten die beiden roten LEDs „leds_static_eyes“ in der Box auf und die Datei 4.mp3 wird wiedergegeben, die auf einer in den MP3-Player-Modul eingesteckten MicroSD-Karte gespeichert werden muss. Wenn wir uns weiter annähern und uns auf eine Entfernung zwischen 150 und 100 cm befinden, bewegt sich die Kiste seitlich mit den Servomotoren 0 und 4. Außerdem wird die Datei 2.mp3 abgespielt. Wenn wir uns noch weiter annähern und uns auf eine Entfernung zwischen 100 und 50 cm positionieren, ändert der Servomotor 1 seine Position, wodurch der Deckel der Kiste langsam geöffnet wird, die beiden anderen roten LEDs "servo_leds_eyes" leuchten auf und bewegen sich leicht hin und her, gesteuert durch Servomotor 2. Zusätzlich wird die Datei 1.mp3 abgespielt. Schließlich, wenn wir uns auf eine Entfernung von 50 cm oder weniger nähern, leuchten wieder die beiden LEDs "leds_static_eyes" auf und der Servomotor 3 ändert seine Position, sodass eine kleine Klaue aus der Kiste herausragt. Sie bewegt sich leicht, als ob sie uns greifen möchte. Dazu wird die Datei 2.mp3 abgespielt.

Alle zuvor beschriebenen Aktionen werden fortlaufend wiederholt, solange wir uns in der entsprechenden Entfernung befinden.

Ich erkläre nun den Sketch (Programmcode).

Der erste Schritt in jedem Sketch besteht darin, die erforderlichen Bibliotheken zu inkludieren, damit wir die verwendeten Module nutzen können. Die ersten beiden hinzugefügten Bibliotheken sind erforderlich, um das Mini MP3 DFPlayer-Modul zu verwenden. Für die Kommunikation zwischen dem MP3-Modul und dem Mikrocontroller aktivieren wir mit der SoftwareSerial.h-Bibliothek die Funktionalität, mit der der Mikrocontroller einen beliebigen digitalen Pin als serielle Schnittstelle verwenden kann. Mit der zweiten Bibliothek (DFRobotDFPlayerMini.h) aktivieren wir die erforderlichen Funktionen zur Verwendung des Moduls.

#include <SoftwareSerial.h>
#include <DFRobotDFPlayerMini.h>

Die nächsten beiden Bibliotheken werden hinzugefügt, um das PCA9685-Servomotor-Steuermodul zu verwenden. Die erste davon, Wire.h, wird für die I2C-Kommunikation zwischen dem Mikrocontroller und dem PCA9685-Modul benötigt. Mit der Adafruit_PWMServoDriver.h-Bibliothek aktivieren wir die erforderlichen Funktionen, um die Servomotoren zu steuern.

#include <Wire.h>
#include <Adafruit_PWMServoDriver.h>

Die letzte hinzugefügte Bibliothek ist "SR04.h". Diese Bibliothek aktiviert die Methoden und Anweisungen, die wir verwenden werden, um mit dem Ultraschallsensor-Modul zu arbeiten.

#include "SR04.h"

(abhängig davon, wie Sie die Bibliotheken installieren, werden sie entweder mit doppelten Anführungszeichen, oder in spitzen Klammern inkludiert)

Nachdem wir die erforderlichen Bibliotheken hinzugefügt haben, müssen wir für jedes Modul oder jeden erforderlichen Bestandteil ein Objekt implementieren. Um das MP3-Player-Modul zu verwenden, müssen wir das Objekt "mySoftwareSerial" aus der Bibliothek "SoftwareSerial.h" implementieren, um dem Mikrocontroller die verwendeten digitalen Pins für die serielle Kommunikation mit dem Modul mitzuteilen. In diesem Projekt verwenden wir den digitalen Pin 10 zum Empfangen von Daten und den digitalen Pin 11 zum Senden von Daten an das MP3-Modul. Um die Methoden und Anweisungen zur Steuerung des Moduls zu verwenden, wie z.B. die Lautstärkeanpassung oder das Starten der Wiedergabe einer MP3-Datei, erstellen wir das Objekt "myDFPlayer" aus der Bibliothek "DFRobotDFPlayerMini.h".

SoftwareSerial mySoftwareSerial(10, 11);
DFRobotDFPlayerMini myDFPlayer;

Für das PCA9685-Modul wird das Objekt "servoDriver_module" aus der Bibliothek "Adafruit_PWMServoDriver.h" erzeugt. Außerdem der minimale und maximale Pulsweitenwert für die Servomotoren. Das entspricht den Positionen 0 Grad und 180 Grad.

Adafruit_PWMServoDriver servoDriver_module = Adafruit_PWMServoDriver();

#define SERVOMIN  100
#define SERVOMAX  500

Die Pins für das Ultraschallsensor-Modul werden als Konstanten deklariert. Wir müssen auch ein SR04-Objekt implementieren und eine Variable für das Ergebnis der berechneten Distanz erstellen. Der TRIG-Pin wird mit Pin 3 des Mikrocontrollers verbunden. Darüber wird das Aussenden des Ultraschallsignals angestoßen (getriggert). Der ECHO-Pin ist Pin 2 am Mikrocontroller. Das ist das empfangene Signal (Echo). Daraus wird die Entfernung berechnet.

#define TRIG_PIN 3
#define ECHO_PIN 2
SR04 ultrasonics_sensor = SR04(ECHO_PIN,TRIG_PIN);
long distance;

Die letzten beiden Zeilen dieses Abschnitts sind die Variablen für die Ausgangspins des Mikrocontrollers, an die die LEDs angeschlossen sind. Der Variablen "leds_static_eyes" weisen wir den Wert 4 zu. Die Variable "servo_leds_eyes" bekommt den Wert 5, also Pin 4 und Pin 5 für jeweils zwei rote LEDs.

int leds_static_eyes = 4;
int servo_leds_eyes = 5;

Danach folgt nun der Abschnitt für die setup()-Methode

In den ersten beiden Zeilen initialisieren wir die Kommunikation an der Software-Serial-Schnittstelle für das MP3-Modul mit der Anweisung "mySoftwareSerial.begin(9600)". Für die serielle Konsole verwenden wir "Serial.begin(115200)". Beachten Sie die unterschiedlichen Baudraten, das ist Absicht.

mySoftwareSerial.begin(9600);
Serial.begin(115200);

Als Nächstes überprüfen wir, ob das MP3-Modul initialisiert wurde. Hierfür verwenden wir eine bedingte Anweisung. Wir verwenden das Ausrufezeichen (!) als Negierung, um abzufragen, ob das MP3-Modul nicht initialisiert wurde. Wenn das der Fall ist, wird der Code innerhalb der geschweiften Klammern ausgeführt. In diesem Fall geben wir über die serielle Konsole eine Meldung aus, in der wir die Überprüfung der Verbindungen und des Einsetzens der microSD-Karte anweisen. Wenn das MP3-Modul erfolgreich initialisiert wurde, wird die Bedingung nicht erfüllt und der Code wird fortgesetzt. Dann wird über die serielle Konsole eine Meldung auszugeben, dass das DFPlayer-Modul ordnungsgemäß initialisiert wurde.

if (!myDFPlayer.begin(mySoftwareSerial)) {
            Serial.println(F("Error initializing mp3 module:"));
            Serial.println(F("1. Please check the connections!"));
            Serial.println(F("2. Please insert the microSD memory!"));
            while(true){
                  delay(0);
            }
      }
     
Serial.println(F("Correct DFPlayer initialization.")); 

Danach folgt die Initialisierung das PCA9685-Moduls mit der Methode begin(). In nächsten Zeile legen wir die Arbeitsfrequenz der Servomotoren mit der Funktion setPWMFreq(50) auf 50 Hz fest. Anschließend rufen wir die Methode home() auf, um die Servomotoren in die Ausgangspositionen zu bringen.

servoDriver_module.begin();
servoDriver_module.setPWMFreq(50);
home();

In den nächsten vier Zeilen konfigurieren wir die digitalen Pins, an die wir die LEDs angeschlossen haben, als Ausgang und setzen den anfänglichen Zustand beider Pins auf LOW, wodurch die LEDs nicht leuchten.

pinMode (leds_static_eyes, OUTPUT);
digitalWrite (leds_static_eyes, LOW);   
pinMode (servo_leds_eyes, OUTPUT);
digitalWrite (servo_leds_eyes, LOW);

In den beiden letzten Zeilen der setup()-Methode konfigurieren wir Trigger- und Echo-Pin des Ultraschallmoduls am Mikrocontroller als Aus- bzw. Eingang.

pinMode (TRIG_PIN, OUTPUT);
pinMode (ECHO_PIN, INPUT);

Wir haben jetzt unsere Projektmodule vollständig konfiguriert. Jetzt müssen wir die loop()-Methode programmieren, damit das gesamte Set die gewünschten Bewegungen ausführt. Die erste Zeile in der Methode ist ein Aufruf der Methode measure_distance(). Diese Methode misst die Entfernung zwischen einem Objekt und dem Ultraschallsensor. In der Zeile distance = ultrasonics_sensor.Distance() messen wir den Abstand zum nächsten Objekt und speichern seinen Wert in der zuvor deklarierten Variablen distance. Mit den nachfolgenden drei Zeilen geben wir den gemessenen Entfernungswert über die serielle Konsole aus. Die letzte Zeile der Methode erzeugt eine Pause von 100 Millisekunden.

measure_distance();
  . . . . .
  . . . . .
  . . . . .
void measure_distance() {
      distance = ultrasonics_sensor.Distance();
      Serial.print("Distance to obstacles ");
      Serial.print(distance);
      Serial.println(" cm");
      delay(100);
}

Die Ausführung des folgenden Codes ist abhängig von der gemessenen Entfernung. Ist der Abstand kleiner als 200 cm und größer oder gleich 150 cm, wird zuerst die Lautstärke verändert. Anschließend wird die Datei 4.mp3 abgespielt. Diese Datei muss auf der eingesteckten SD-Karte gespeichert sein und enthält einen Monsterschrei.

Um den Eindruck zu erwecken, dass sich ein Monster in der Kiste befindet, leuchten außerdem zwei rote LEDs auf, die durch ein Loch in der Kiste sichtbar sind.

Wichtiges zur Tonausgabe: Die Wiedergabe des Tones beginnt mit der jeweiligen Anweisung und der nächste Code wird ausgeführt. Der Ton wird jedoch weiterhin bis zum Ende abgespielt, während der Mikrocontroller die nächsten Anweisungen ausführt.

if (distance < 200 && distance >= 150) {

  myDFPlayer.volume(15);
  myDFPlayer.play(4);
            
  digitalWrite (leds_static_eyes, HIGH);
  delay(6000);
  digitalWrite (leds_static_eyes, LOW);
  delay(3000);
}

Wenn sich ein Objekt in einer Entfernung von weniger als 150 cm oder mehr als 100 cm befindet, wird wieder die Lautstärke verändert und anschließend die Datei 2.mp3 abgespielt.

Außerdem verwenden wir zwei Servomotoren an den Seiten der Kiste, als ob sich etwas im Inneren bewegt und dagegen stoßen würde. Um dies zu erreichen, ändern wir den Positionsparameter des Servomotors 0, der sich auf der linken Seite der Kiste befindet, und des Servomotors 4, der sich auf der rechten Seite befindet. Wir verwenden eine `for`-Schleife, die die Bewegungen insgesamt fünfmal durchführt. Innerhalb der Schleife ändern wir die Positionen der beiden Servomotoren. Nach jeder neuen Positionsänderung erfolgt eine Wartezeit von 200 ms. Nach Abschluss der fünf Durchläufe wird die Schleife beendet und es erfolgt eine Wartezeit von 5 Sekunden.

if (distance < 150 && distance > 100) {
        
  myDFPlayer.volume(15);          
  myDFPlayer.play(2);                    
            
  for (int n=0; n<5; n +=1) {                          
    servoDriver_module.setPWM(0, 0, 120);                      
    delay(200);                                     
    servoDriver_module.setPWM(0, 0, 180);                         
    delay(200);                                     
    servoDriver_module.setPWM(4, 0, 230);                        
    delay(200);                                        
    servoDriver_module.setPWM(4, 0, 170);                         
    delay(200);                                      
  }
            
  delay(5000);    
}

Wenn die gemessene Entfernung weniger oder gleich 100 cm und größer als 50 cm ist, wird erneut die Lautstärke verändert und dieses Mal die Datei 1.mp3 abgespielt.

Sobald der Ton abgespielt wird, öffnet sich langsam der Deckel, als würde das Monster hervorschauen. Es werden zwei LEDs als Augen leuchten und sich ein paar Mal seitwärts bewegen, bevor es sich wieder schnell versteckt. In einer Schleife wird die Position des zugehörigen Servos Nr. 1 verändert. Nach der Änderung der Servoposition, werden die Zustände der LED-Pins verändert. Wenn sie leuchten, sollen sie sich seitlich bewegen. Mit einer weiteren Schleife wird die Position des dazugehörigen Servos Nr. 2 verändert. Das läuft zwei Mal durch. Anschließend werden alle Servos auf die Grundposition zurückgestellt und die LEDs ausgeschaltet.

if (distance <= 100 && distance > 50) {
        
  myDFPlayer.volume(15);
  myDFPlayer.play(1);
            
  for (int pos=400; pos>160; pos -=2) {
    servoDriver_module.setPWM(1, 0, pos);
    delay(10);
  }
            
  digitalWrite (servo_leds_eyes, HIGH);
  delay(1000);
            
  for (int n=0; n<2; n +=1) {
    servoDriver_module.setPWM(2, 0, 125);
    delay(1000);
    servoDriver_module.setPWM(2, 0, 275);
    delay(1000);
  }
            
  servoDriver_module.setPWM(2, 0, 200);
  delay(1000);
  servoDriver_module.setPWM(1, 0, 400);
  delay(50);
  digitalWrite (servo_leds_eyes, LOW);
            
  delay(5000);
}

Ist der gemessene Abstand kleiner als 50 cm, wird auch hier die Lautstärke verändert und die Datei 2.mp3 abgespielt.

Nun möchten wir, dass das Monster eine Klaue durch das untere rechte Loch der Kiste schiebt. Um dies zu erreichen, verwenden wir die Bewegung des Servomotors 3, an dem wir die Klaue befestigt haben. Wenn die Klaue aus der Kiste herausragt, werden die statischen LEDs wie Augen leuchten. Das wird drei Mal wiederholt. Die Klaue zieht sich ein Stück zurück und wird dann wieder ganz nach außen positioniert. Diese Bewegung wird auch drei Mal durchgeführt. Danach wird die Position des Servos zurückgesetzt und die LEDs werden ausgeschaltet.

if (distance <= 50) {
        
  myDFPlayer.volume(15);
  myDFPlayer.play(2);
            
  servoDriver_module.setPWM(3, 0, 100);
  digitalWrite (leds_static_eyes, HIGH);
  delay(1000);
            
  for (int n=0; n<3; n +=1) {
    servoDriver_module.setPWM(3, 0, 150);
    delay(500);
    servoDriver_module.setPWM(3, 0, 100);
    delay(500);
  }
            
  servoDriver_module.setPWM(3, 0, 230);
  digitalWrite (leds_static_eyes, LOW);
            
  delay(5000);
}

Die Methode home() wird verwendet, um alle Servomotoren in ihre Ausgangspositionen zu bringen. Sie wird bei Programmstart im setup() ausgeführt, um sicherzustellen, dass alle Komponenten aus einer bekannten Position starten.

void home() {
  
  servoDriver_module.setPWM(0, 0, 180);
  servoDriver_module.setPWM(1, 0, 400);
  servoDriver_module.setPWM(2, 0, 200);
  servoDriver_module.setPWM(3, 0, 230);
  servoDriver_module.setPWM(4, 0, 170);
  delay(1000);
      
}

Sketch als Download: the_box_monster.ino

Wir hoffen, dass Sie eine gruselig unterhaltsame Halloween-Nacht und Spaß beim Bau dieses Projekts haben.

Happy Halloween.

 

 Hier noch die Links zu den Halloween-Projekten der letzten Jahre:

• Halloween 2022 - Der Süßigkeitenwächter
• Scary, spooky Halloween 2022
• Die Augen des Kürbisses - Halloween kommt ganz plötzlich
• Halloween Kürbis 2.0
• Skull: Halloween 2020
• Halloween 2019 - Der Kürbis erwacht wieder

Update

Der Leser Sascha Stiefenhofer hat das Projekt für den 3D-Drucker aufbereitet und via Thingiverse zur Verfügung gestellt, vielen Dank an dieser Stelle:

Quelle: Thingiverse

Der Leser Lars hat uns seine Bilder der Box zur Verfügung gestellt, auch dafür vielen Dank:

Der Leser Philipp hat ebenfalls sein Projekt via Thingiverse als 3D-Modell zur Verfügung gestellt:

Quelle: thingiverse